Análise de medidas repetidas no tempo



Baixar 231.16 Kb.
Página1/2
Encontro25.03.2018
Tamanho231.16 Kb.
  1   2


ANÁLISE DE MEDIDAS REPETIDAS NO TEMPO

USANDO O SAS
Euclides Braga MALHEIROS*

Medidas repetidas no tempo ou espaço: medidas tomadas em uma seqüência de tempos ou espaços, em uma mesma unidade experimental.


Os experimentos com medidas repetidas no tempo envolvem geralmente, além de possíveis fatores de controle local, 2 fatores: tratamentos e tempos, e são freqüentes em experimentos com animais, plantas, humanos, etc. O objetivo principal desse tipo de experimento é examinar e comparar as tendências dos tratamentos ao longo do tempo. Isto pode envolver comparações entre tratamentos dentro de cada tempo, ou comparações de tempos dentro de cada tratamento.

Exemplo1:

Cinco variedades de uma cultura (tratamentos), com 3 repetições, avaliadas ao longo do tempo (0, 30, 60, 90, 120 e 150 dias), em um experimento Inteiramente Casualizado.



Os dados observados são apresentados na Tabela 1.
Tabela 1. Dados de açúcar na cana, (pol%), obtidos em um DIC com 5 variedades de cana, 3 repetições, observados em 6 tempos de desenvolvimento da cultura.

Variedades

Rep.

Tempo em dias

0

30

60

90

120

150

V1

1

11,82

14,86

13,84

15,53

15,49

15,82

2

12,07

14,44

13,92

15,47

16,34

18,64

3

12,45

14,18

13,76

14,35

15,93

16,52

V2

1

12,47

15,19

15,02

15,54

18,53

15,76

2

11,07

13,38

14,61

14,07

17,84

16,91

3

10,66

14,22

13,54

15,93

15,94

16,81

V3

1

12,92

14,49

13,40

13,68

16,26

14,78

2

10,29

14,42

14,62

15,84

16,29

15,62

3

12,83

13,92

15,69

15,12

14,91

17,22

V4

1

11,96

14,71

14,98

15,25

16,21

15,53

2

13,38

15,07

13,62

15,39

15,77

16,51

3

10,37

15,78

13,33

14,50

16,66

16,34

V5

1

11,05

13,18

14,61

14,88

16,51

16,36

2

10,63

13,14

14,53

14,21

16,57

15,24

3

13,43

14,08

14,23

14,11

15,86

17,50

Fonte: Nogueira (1995)
MÉTODOS PARA ANALISAR MEDIDAS REPETIDAS NO TEMPO
1. Análise como parcelas subdivididas.

Na literatura, encontram-se muitas abordagens para analisar dados em medidas repetidas (no tempo ou no espaço). Um procedimento comum é analisar os dados como se fosse um experimento em Parcelas Subdivididas. O problema é que no delineamento em parcelas subdivididas pressupõe-se que a matriz de covariâncias entre as subparcelas seja do “Tipo 2I”, devido a casualização das mesmas dentro das parcelas, o que não ocorre em ensaios com medidas repetidas. Isso resulta muitas vezes em testes F incorretos na Análise da Variância. Veja Anexo 1.

Pelo Anexo, a matriz de variâncias e covariâncias entre tempos é:

=,

onde i2 é a variância no tempo i, e ij é a covariância entre os tempos i e j. Na estrutura homogênea i2=2 ,  i e ij=,  ij.

Essa estrutura não é a esperada para dados com medidas repetidas no tempo, o que faz com que os testes F correspondentes a Tempo e interação Tempo x Trat podem não serem exatos.

O que se encontra na literatura é que as medidas repetidas em uma mesma unidade experimental (animal, plantas ou humanos) são correlacionadas e que medidas em tempos mais próximos apresentam correlações mais altas que em tempos mais distantes. Uma estrutura que tem sido estudada é a autoregressiva.

Segundo Huynh & Feldt (1970) uma condição necessária e suficiente para que os testes F sejam exatos, é que a matriz  satisfaça a condição de esfericidade (ou circularidade), ou seja, que satisfaça a condição:



,

onde é a diferença entre as médias das variâncias e as medias das covariâncias.

Esta condição, denominada condição H-F ou condição de esfericidade (ou circularidade) da matriz , eqüivale a especificar que as variâncias das diferenças entre pares de tempos sejam todas iguais, ou seja:

.

Para exemplificar, verifique se a matriz abaixo satisfaz a condição de esfericidade:



Observe que :

;

; e assim por diante.

Logo a matriz satisfaz a condição de esfericidade.
Em 1984 o comando REPEATED foi incluído no PROC GLM do SAS, onde o teste de esfericidade , teste de Murchly, é realizado.
Teste de Esfericidade da matriz usando o comando REPEATED do PROC GLM.

Este comando do SAS exige que os Dados estejam na forma Multivariada (ver Anexo 2).



Sintaxe:

PROC GLM <opções 1>;

CLASS <fator Tra.>;

MODEL <Lista Var.Tempo>=<fator Trat.>/<opções 2>;

REPEATED <fator tempo> <nº níveis fator tempo> [<(níveis fator tempo)>] <tipo de contrastes>/<opções 3>;

RUN;

Uma das possíveis <opções 1> é:

  • DATA= - especifica o SAS-DATA-SET a ser usado.

Uma das possíveis <opções 2> é:

  • NOUNI – não executa as análises unidimensionais, dentro de cada tempo.

Alguns dos possíveis <tipos de contrastes> são:

  • CONTRAST [(nível referencial)] – gera contrastes entre cada nível do fator tempo com o nível referencial. Quando o nível referencial não for especificado, considera o último.

  • POLYNOMIAL – gera contrastes de polinômios ortogonais para os níveis do fator tempo.

  • HELMERT – gera contrastes entre cada nível do fator tempo com a média dos subsequentes.

  • MEAN (nível referencial) – gera contrastes entre o cada nível (exceto o referencial) com a média dos outros.

  • PROFILE – gera contrastes entre níveis adjacentes do fator tempo.

A colocação dos níveis do fator tempo é opcional se forem equidistantes e necessário se não forem.

Algumas das <opções 3> são:

  • CANONICAL – executa uma análise canônica das matrizes H e E.

  • HTYPE=n – especifica o tipo da soma de quadrados a ser usado.

  • NOM – Não executa a análise multivariada.

  • NOUNI – Não executa as análises univariadas.

  • PRINT|E|H|M|V – Imprime a matriz especificada:

E - matriz da soma de quadrados dos produtos cruzados para erros. Com a opção PRINTE o SAS apresenta o teste de esfericidade da matriz de covariâncias.

H - matriz da soma de quadrados dos produtos cruzados (SS&CP) para a Hipótese.

M - matriz dos contrates.

V - matriz dos auto-valores e auto-vetores associada ao teste.

  • SUMMARY – apresenta a tabela da análise da variância dos contrastes para o fator tempo.

Exercício 1 – (PROG1.SAS)

Fazer um programa SAS para:



  1. Criar um SDS Importando o arquivo ASC II univariado (MRT1U.txt)

  2. Representar graficamente os perfis médios das variedades ao longo do tempo.

  3. Criar um SDS multivariado (MRT1M).

  4. Testar a esfericidade da matriz.

  5. Se a matriz for esférica realizar a análise da variância como parcelas subdivididas, caso contrário crie um SDS permanente para MRT2U e MRT2M, para posterior análise.


PROGRAMA (Prog_1.SAS):

/* EXEMPLO 1 - TESTE DA ESFERICIDADE DA MATRIZ*/

OPTIONS LS=78 PS=64;

DATA MRT1U;

INFILE "C:\S_MRT\MRT1U.TXT";

INPUT VR TP RP Y;

PROC PRINT;

RUN;
/* REPRESENTACAO GRAFICA - TENDENCIA DOS TRATAMENTOS AO LONGO DO TEMPO */

OPTIONS LS=78 PS=64;

PROC SORT DATA=MRT1U; BY VR TP; RUN;

PROC MEANS MEAN NOPRINT;

OUTPUT OUT=MRT1G MEAN=YG;

BY VR TP;

VAR Y;

RUN;

PROC PRINT DATA=MRT1G; RUN;

PROC SORT DATA=MRT1G; BY TP VR;

PROC GPLOT DATA=MRT1G;

PLOT YG*TP=VR/LEGEND GRID HAXIS=0 TO 150 BY 30;

SYMBOL1 COLOR=RED INTERPOL=JOIN VALUE=DOT;

SYMBOL2 COLOR=BLUE INTERPOL=JOIN VALUE=DOT;

SYMBOL3 COLOR=GREEN INTERPOL=JOIN VALUE=DOT;

SYMBOL4 COLOR=BLACK INTERPOL=JOIN VALUE=DOT;

SYMBOL5 COLOR=ORANGE INTERPOL=JOIN VALUE=DOT;

TITLE HEIGHT=1.4 "TENDENCIA DOS TRAT. AO LONGO DO TEMPO";

RUN;
/*CRIACAO DO SAS-DATA-SET MULTIVARIADO A PARTIR DO UNIVARIADO */

PROC SORT DATA=MRT1U; BY VR RP;

PROC TRANSPOSE OUT=MRT1M(RENAME=(_0=T1 _30=T2 _60=T3 _90=T4 _120=T5 _150=T6));

BY VR RP;

ID TP;

RUN;

PROC PRINT DATA=MRT1M;

RUN;
/* Análise usando o comando REPEATED do PROC GLM */

PROC GLM DATA=MRT1M;

CLASS VR;

MODEL T1-T6=VR/NOUNI;

REPEATED TP 6 POLYNOMIAL/PRINTE SUMMARY;

RUN;
/* Análise como parcelas subdivididas */

PROC GLM DATA=MRT1U;

CLASS VR RP TP;

MODEL Y=VR RP(VR) TP VR*TP/SS3;

RANDOM RP(VR)/TEST;

MEANS VAR/TUKEY E=RP(TR);

LSMEANS VR*TP/SLICE=TP;

LSMEANS VR*TP/SLICE=VR;

RUN;
Resultado Gráfico:



Resultados do Teste de esfericidade.
Sphericity Tests

Mauchly's

Variables DF Criterion Chi-Square Pr > ChiSq

Transformed Variates 14 0.1956602 13.214144 0.5097

Orthogonal Components 14 0.1956602 13.214144 0.5097
O SAS apresenta 2 testes de esfericidade. O primeiro depende do tipo de contrastes solicitado e o segundo é válido para qualquer conjunto de contrastes ortogonais.

Observa-se com esses resultados que a condição de esfericidade da matriz é rejeitada ao nível de 10% de probabilidade. Assim sendo os dados podem ser analisados como Parcelas subdivididas.


Exemplo 2:

Dados de IAF de 5 genótipos de leguminosa, obtidos num experimento DBC com 4 blocos, avaliados em 7 épocas (dias) - apresentados na Tabela 2.


Exercício 2 – (Prog_2.SAS)

Fazer um programa SAS para:



  1. Criar um SDS Importando o arquivo ASC II multivariado (MRT2M.txt).

  2. Criar um SDS uniivariado (MRT2U).

  3. Representar graficamente os perfis médios das variedades ao longo do tempo.

  4. Testar a esfericidade da matriz.

  5. Se a matriz for esférica realizar a análise da variância como parcelas subdivididas, caso contrário crie um SDS permanente para MRT2U e MRT2M, para posterior análise.

Tabela 2. Dados de IAF de 5 genótipos de leguminosa, obtidos num experimento DBC com 4 blocos, avaliados em 7 épocas (dias)

Genótipo

Bloco

Número de dias

88

104

120

137,5

153,5

181,5

209,5

1

1

0,13

0,39

0,46

0,52

1,18

0,87

0,51

1

2

0,31

0,25

1,07

0,44

1,11

1,41

1,08

1

3

0,22

0,40

0,53

3,61

1,11

0,98

0,78

1

4

0,08

0,17

0,97

1,11

1,70

0,92

0,74

2

1

0,13

0,36

0,89

0,62

1,64

1,61

1,42

2

2

0,27

0,10

0,53

0,60

1,52

1,01

1,09

2

3

0,13

0,41

1,03

3,60

1,92

0,56

1,09

2

4

0,08

0,55

0,62

1,04

2,47

1,45

1,12

3

1

0,84

1,44

2,31

6,07

3,90

3,42

2,00

3

2

0,45

1,18

2,66

3,88

4,03

3,09

0,99

3

3

0,67

2,39

4,25

6,33

4,13

3,46

0,96

3

4

1,28

3,45

5,04

5,57

3,87

0,36

0,77

4

1

0,42

0,80

0,72

1,07

1,20

1,08

1,26

4

2

0,15

0,40

0,42

0,85

0,66

0,85

0,71

4

3

0,22

0,30

0,77

0,94

1,44

1,49

0,62

4

4

0,28

0,36

0,74

0,73

1,62

1,84

1,36

5

1

0,67

1,77

2,09

3,27

3,92

2,36

2,72

5

2

0,66

1,07

2,39

4,19

4,89

1,86

1,61

5

3

1,41

2,55

3,87

4,62

3,62

3,87

0,02

5

4

1,30

2,16

5,78

8,62

7,92

0,26

0,26

Fonte: Castro (1999)

PROGRAMA (Prog_2.SAS):

/* EXEMPLO 2 - ANÁLISE DE DADOS EM MEDIDAS REPETIDAS NO TEMPO*/

/* DADOS NA FORMA MULTIVARIADA*/

OPTIONS LS=78 PS=64;

DATA MRT2M;

INFILE "C:\S_MRT\MRT2M.TXT";

INPUT GN BL T1-T7;

PROC PRINT DATA=MRT2M;

RUN;

/* GERAR O SDS NA FORMA UNIVARIADA*/

DATA MRT2U (KEEP=GN BL TP Y);

SET MRT2M;

TP=88; Y=T1; OUTPUT MRT2U;

TP=104; Y=T2; OUTPUT MRT2U;

TP=120; Y=T3; OUTPUT MRT2U;

TP=137.5; Y=T4; OUTPUT MRT2U;

TP=153.5; Y=T5; OUTPUT MRT2U;

TP=181.5; Y=T6; OUTPUT MRT2U;

TP=209.5; Y=T7; OUTPUT MRT2U;

RUN;

PROC PRINT DATA=MRT2U;

RUN;

/* REPRESENTACAO GRAFICA - TENDENCIA DOS TRATAMENTOS AO LONGO DO TEMPO */

PROC SORT DATA=MRT2U; BY GN TP; RUN;

PROC MEANS MEAN NOPRINT;

OUTPUT OUT=MRT2G MEAN=YG;

BY GN TP;

VAR Y; RUN;

PROC PRINT DATA=MRT2G; RUN;

PROC GPLOT DATA=MRT2G;

PLOT YG*TP=GN/LEGEND GRID;

SYMBOL1 COLOR=RED INTERPOL=JOIN VALUE=DOT;

SYMBOL2 COLOR=BLUE INTERPOL=JOIN VALUE=DOT;

SYMBOL3 COLOR=GREEN INTERPOL=JOIN VALUE=DOT;

SYMBOL4 COLOR=BLACK INTERPOL=JOIN VALUE=DOT;

SYMBOL5 COLOR=ORANGE INTERPOL=JOIN VALUE=DOT;

TITLE HEIGHT=1.4 "TENDENCIA DOS TRAT. AO LONGO DO TEMPO";

RUN;

/* Análise usando o comando REPEATED do PROC GLM */

PROC GLM DATA=MRT2M;

CLASS BL GN;

MODEL T1-T7=BL GN/NOUNI;

REPEATED TP 6 (88 104 120 137.5 153.5 181.5 209.5) POLYNOMIAL/PRINTE SUMMARY;

RUN;
* CRIANDO SDS PERMANENTES;

LIBNAME LOCAL "C:\S_MRT";

DATA LOCAL.MRT2U; SET MRT2U;

DATA LOCAL.MRT2M; SET MRT2M;

RUN;
Gráfico dos perfis médios dos Genótipos ao longo do Tempo

Resultados do teste de esfericidade.


Sphericity Tests - Mauchly's

Variables DF Criterion Chi-Square Pr > ChiSq

Transformed Variates 20 0.0021259 60.168021 <.0001

Orthogonal Components 20 0.0021259 60.168021 <.0001


Observa-se com esses resultados que a condição de esfericidade da matriz é rejeitada, ao nível de 10% de probabilidade. Assim sendo os testes F da análise em parcelas subdivididas não são exatos.


  1. Análise usando o PROC MIXED.

O PROC MIXED é um procedimento utilizado para modelos mistos que é uma generalização do modelo linear geral, separando no modelo os efeitos fixos dos aleatórios e é escrito como: y=X+Z+ onde é o vetor dos parâmetros associados aos efeitos fixos, aos efeitos aleatórios, e vetor de erros aleatórios, sendo e não correlacionados, com esperanças nulas e matrizes de covariâncias G e R, respectivamente.

O PROC MIXED permite informar a estrutura da matriz (G), através do comando RANDOM, e a dos erros (R) ), através do comando REPEATED.

Para este tipo de análise os dados devem estar na forma univariada.

A sintaxe do PROC MIXED é:

PROC MIXED <opções1>;

CLASS <var. de classif.>;

MODEL <var. dep.>= / <opções2>;

RANDOM <efeitos aleatórios em G> / ;



Compartilhe com seus amigos:
  1   2


©ensaio.org 2017
enviar mensagem

    Página principal